mel wiki

How can I build a file browser dialog, to select a file that dosn't yet exist? Or to select a directory only?

Fri, 12 Mar 2010 22:18:39 GMT

fileBrowserDialog

Notes: The docs on this suck, so this is what you need to do:

Example with Python, for picking directories. Since you can nest functions in Python, it makes it easier to wrapper the functionality of this command together into one cohesive unit.

import maya.cmds as mc
def fbd():
    def fileCommand(directory, ignore):
        # This is called by the fileBrowserDialog command after a dir is picked.
        print directory
    mc.fileBrowserDialog(mode=4, fileCommand=fileCommand, fileType='directory',
                         actionName='Choose a directory:')
fbd()

Mel Examples:
- First, built the file brower dialog: -mode is telling it what to do:

fileBrowserDialog -mode 2 -fileCommand "procName" 
    -actionName "whatYouAreDoing";

-mode 0 is for reading files, so if you type in a name that dosn't exist, the browers will give an error
-mode 1 & 2 are pretty much the same and are for for writing to file, so you can speficy your own filename in the browers.
-mode 4 is for selecting directories only.
-fileCommand is the name of the below proc, that the fileBrowserDialog? passes its info to.
-actionName is simply what is printed in the UI, telling the user what is going on
If you're using mode 1 or 2, and you want to specify your own "file types" for filtering, you can use the below code snippet (thanks to Mason Sheffield).
- The -filterList can be called to multiple times to define different file types. The -filterType is simply the default UI filterList choice. Also, you must set -dialogStyle 1 for some reason, or the filtering won't work :(

-filterList "My file type(*.mft),*.mft" 
-filterList "otherFileType(*.oft),*.oft"
-fileType "My file type(*.mft)" 
-dialogStyle 1

Next, you need to build a proc, that can take the return from the FBD, and then do something with it. It needs to be in the below format, but the proc name, and var names can change.

global proc procName(string $result, string $type){
    textFieldButtonGrp -e -tx $result controlName;}

So, the fileBrowserDialog passes its info, via the $result argument, into the "procName" proc. Then procName will update controlName with $result.

Another issue: By default you can't specify WHERE the dialog will open too. It appears that it bases where it opens on where Maya's current workspace is. SO, to tell it where to go, you'd need to do something like this:

// query Maya's current workspace:  
string $mayaWorkspace = `workspace -q -dir`;
// set the workspace to where you want the dialog to open:
workspace -dir $myCustomPath;
// run the dialog code:
fileBrowserDialog ....
// and set the workspace back again:
workspace -dir $mayaWorkspace;

Annoying!

I got an emailed suggestion from Nicolas Combecave. Thanks Nicolas!

After scrutining into the fileBrowser mel command, I found that the script fileBrowserWithFilter, does both in one single command, plus adds an items filtering mechanism. Here is its syntax from the procedure declaration:

global proc int fileBrowserWithFilter(
    string $callBack, 
    string $action, 
    string $title, 
    string $type, 
    int $mode, 
    string $filters[], 
    string $dir)

We can translate it into a mode understandable text:
- string $callBack > your procedure to launch upon validation
- string $action > text label on the validation button
- string $title > browser title
- string $type > a filetype to select in the dropdown list. Even custom ones (see below).
- int $mode > choose for read/write/listDirs... (see description above)
- string $filters[] > fileTypes in the dropdown menu. You can define yours here: {"myFileType,*.mft":"yourFileType,*.yft":"theirFileType,*.tft":etc...}
- string $dir > the starting directory
So you can use it when you want to specify a file that doesn't exists, into a specified destination, filtering only special file types, even custom ones:

string $startDir  ="c:/tmp/";
fileBrowserWithFilter(
    "procName",
    "myLabel",
    "myTitle",
    "afileType",
    1,
    {"aFileType,*.aft","anotherFileType,*.anft"},
    $startDir);

Qt UI Authoring

Fri, 12 Mar 2010 21:30:00 GMT

Starting in Maya 2011, Autodesk changed the UI system to Qt (made by Nokia). I'm not 2011 yet... but I found this snazzy video blog discussing some of the high level features:

http://area.autodesk.com/blogs/stevenr/maya_2011_highlight_qt_user_interface

How can I set the range slider to match the keyframe range of all nodes in the scene?

Mon, 08 Mar 2010 17:42:00 GMT

# Python code
import maya.cmds as mc
animCurves = mc.ls(type='animCurve')
first = mc.findKeyframe(animCurves, which='first')
last = mc.findKeyframe(animCurves, which='last')
mc.playbackOptions(min=first, max=last)

How can I set the range slider to match the keyframe range on the selected object(s)?

Mon, 08 Mar 2010 17:20:00 GMT

selectKey -time ":";
float $allKeys[] = sort(`keyframe -q -sl`);
playbackOptions -min $allKeys[0] -max $allKeys[(size($allKeys) -1)];

Also see:

How can I parent the instance of a shape node from one object to another?

Wed, 03 Mar 2010 18:23:00 GMT

New way my buddy Te pointed out to me:

# Python code:
import maya.cmds as mc
mc.parent('someShapeNode', 'someTransform', shape=True, add=True)

I thought the code would re-parent the shape node. But it doesn't, it makes it an instance.

Older method:

First, you "instance" your shape node, which will give you a new transform as well.
Second, you parent your new instanced shape node to it's new parental transform.
Third, remove the 'no-longer-needed' transform

string $shapeNode = "myShape";
string $newParent = "someTransform";
string $instancedShape[] = `instance $shapeNode`;
parent -s -r ($instancedShape[0] + "|" + $shapeNode) $newParent;
delete $instancedShape[0];

Also see:
How can I reparent the shape node of one object to another. OR, how can I have a single transform with multiple shapes?

Matrix info

Wed, 24 Feb 2010 02:36:00 GMT

When I first authored this subject I didn't use matrices very often. But I've found the more I learn about them, the more I end up using them...
Also see my other subject: Working with matrices with Python

Launch help for the root dagNode type node, which has the base matrix attrs:

showHelp -d "Nodes/dagNode.html

Launch help for the transform node (lots of matrix info):

showHelp -d "Nodes/transform.html";

Web:

I made an image describing how 4x4 matrix multiplication works. You can find it on my blog here, or on flickr here
chapter 9 from the book Beginning Game Development with Python and PyGame: From Novice to Professional has a really well described overview.
http://eddieoffermann.com/blog/tag/matrix-multiplication/
http://www.185vfx.com/2003/03/convert-a-3d-point-to-2d-screen-space-in-maya/
Online video lectures from MIT
http://knol.google.com/k/koen-samyn/matrices-for-3d-applications/2lijysgth48w1/3#

Quick 4x4 matrix review of an identity matrix (presuming +X is 'left', +Y is 'up', and +Z is 'forward'). To visualize the x, y, and z-axes, use your hand: Hold your right hand in front of you, pointer straight ahead, thumb up, and middle-finger left: Middle-finger = +X-axis, thumb = +Y-axis, pointer = +Z-axis.

The fourth column 'W' is for the most part unused, it is always (0, 0, 0, 1): This is called the 'homogeneous row'. W = A scalar value (also known as the 'homogeneous coordinate') used for conversion from Euclidean to Cartesian coordinates.
The first three rows represent the vectors that point in the x, y, and z directions of the transformation, which represent the axis in 3D space. Effectively the orientation/heading of the 'local axis' of a transform in Maya. They also calculate scale.
The fourth row (w) represents the translation, or point in space when transformed by this matrix. This is the 'homogeneous row':

	X	Y	Z	W	notes

x-axis	1	0	0	0	'left', mag=scaleX
y-axis	0	1	0	0	'up', mag=scaleY
z-axis	0	0	1	0	'forward', mag=scaleZ
(w) translate	0	0	0	1

(remember, the right column is ignored)

translation: Derived from the bottom row.
- translateX, translateY, translateZ = (0 ,0 ,0)
orientation: Vectors that point in the x, y, and z directions of the transformation.
- x-axis : defines the current heading of the 'left' vector = (1, 0, 0)
- y-axis : defines the current heading of the 'up' vector = (0, 1, 0)
- z-axis : defines the current heading of the 'forward' vector = (0, 0, 1)
scale : The magnitude of each x, y, and z-axis defines the scale = (1, 1, 1)
- scaleX = mag(x-axis) = mag(1, 0, 0) = 1.0
- scaleY = mag(y-axis) = mag(0, 1, 0) = 1.0
- scaleZ = mag(z-axis) = mag(0, 0, 1) = 1.0
shear : still working on that one ;)

Some examples, based on that info:

Where individual rotation axis data is stored in the matrix:
X-axis:

	X	Y	Z	W

x-axis	1	0	0	0
y-axis	0	1	0	0
z-axis	0	0	1	0
(w) translate	0	0	0	1

Y-axis:

	X	Y	Z	W

x-axis	1	0	0	0
y-axis	0	1	0	0
z-axis	0	0	1	0
(w) translate	0	0	0	1

Z-axis:

	X	Y	Z	W

x-axis	1	0	0	0
y-axis	0	1	0	0
z-axis	0	0	1	0
(w) translate	0	0	0	1

Translate XYZ:

	X	Y	Z	W

x-axis	1	0	0	0
y-axis	0	1	0	0
z-axis	0	0	1	0
(w) translate	0	0	0	1

Identity matrix rotated 45 degrees along the Z axis. Compare this to the above chart that shows where those values will be stored. Note how the z-axis remains the same (0, 0, 1, 0) since it hasn't changed orientation. But both the x-axis and y-axis now have a new heading? (since they were transformed by the z-axis rotation) And notice how all their magnitudes still equals 1.0? Scale remains at (1,1,1).
- Visualize this using the 'left hand rule' described above: Start with your left hand at identity. Imagine there is a point on the tip of each finger corresponding to each identity vector. Now rotate your hand along the z-axis (pointer) clockwise 45 degrees. Your pointer is still pointing the exact same direction (0, 0, 1), but the points defined by your thumb (+y) and middle finger (+x) have moved in space. But they're all still the same distance away from the middle of the transform, so their magnitudes still each equal 1.0.

.707107	-.707107	0	0
.707107	.707107	0	0
0	0	1	0
0	0	0	1

Identity matrix scaled to be half as wide, and twice as high:

scaleX = mag(x-axis) = mag(.5, 0, 0) = .5
scaleY = mag(y-axis) = mag(0, 2, 0) = 2
scaleZ = mag(z-axis) = mag(0, 0, 1) = 1

.5	0	0	0
0	2	0	0
0	0	1	0
0	0	0	1

Maya transformation matrix:
Simple version:

Scale Matrix * Rotate Matrix * Translate Matrix = final matrix

Long version:
matrix = SP *(-1) S * SH * SP * ST * RP *(-1) RA * R * RP * RT * T
* = matrix multiplication, (-1) = matrix inversion

SP = scale pivot
S = scale
SH = shear
ST = scale (pivot) translate
RP = rotate pivot
RA = rotate axis =
- AX * AY * AZ
R = rotate =
- RX * RY * RZ (Defined by rotate order)
RP = rotate pivot
RT = rotate (pivot) translate
T = translate

Matrix multiplication happens in order, from left to right. It can be thought of exactly like a transform hierarchy, with child nodes on the left, and parental nodes on the right. The matrix to the right will effect the matrix to the left. So in effect, the root of the hierarchy is 'T' (translate), while the leaf-most child would be 'S' (scale). This is why the translation of a node effects where it is rotated and scaled, the rotation of a node effects the orientation of scale but has no effect on translation, and the scale of a node has no effect over rotation or translation.

It's important to note that Maya internally doesn't store its animation data as matrices. It stores them on nodes, as keyframe data (scalar values), expression data, dynamic sim, etc. The matrix is simply a state value that can be queried based on the end result of the incoming anim data for a given transform.

Matrices are multiplied together to get new matrices. For example, if you wanted to assign the position of objectC as the position of objectA + objectB:

matrixC = matrixB * matrixA

So when you think of 'adding' values, convert that to 'multiplying' matrices.
But what if you want to 'subtract' values? For example, you want the position of objectC to be the difference between objectA and objectB? In this case you add (multiply) by the inverseMatrix.

matrixC = matrixB * inverseMatrixA

dagNode node's matrix related attrs (all of these are available through any transform based node):

Local matrix data, relative to the nodes parent:
- .matrix : Local transformation matrix for the dagNode.
- .inverseMatrix : Inverse of matrix attribute. Multiplying by this value will place it at its parent.
Matrix data for the nodes parent:
- .parentMatrix : The parentMatrix instanced attribute represents the world-space transformation matrix for the parents of this dagNode. If the dagNode is a transform node and its inheritTransform attribute is false, then the parentMatrix is identity.
- .parentInverseMatrix : Inverse of parentMatrix instanced attribute. Multiply the parent by this value to return it to origin.
Matrix data relative to the world:
- .worldMatrix : The worldMatrix instanced attribute is the 4x4 transformation matrix that transforms the object to world-space. There is a world-space matrix for each unique path to the object. Eg. 'ball.worldMatrix[0]' identifies the world-space transformation matrix for the first instance of the object 'ball'. Each world-space transformation matrix is the result of post multiplying the 'matrix' attribute by corresponding 'parentMatrix' instanced attribute (i.e. worldMatrix[i] == matrix x parentMatrix[i]). Thus, the worldMatrix is the concatenation of the 'matrix' attribute of all the dagNodes along the path from the node up to the root of the dag hierarchy.
  - Basically: dagNode.worldMatrix = dagNode.matrix * dagNode.parentMatrix
- .worldInverseMatrix : Inverse of worldMatrix instanced attribute. Multiplying by this will place it at the world origin.

transform node's matrix related attrs:

.xformMatrix : Local transformation matrix. From the docs: "Contains the same information as the matrix attribute on dagNode but it is stored in a format that can be interpolated easily.". Personally, I'm not sure what makes it more easy to interpolate.

It should be noted that on all these attrs you can connect to or query their outputs, but they don't allow for input connections or modifications via setAttr.

Notes on getting Matrix attr data:

Some attributes represent transformation matrices. Although these attributes are represented internally as 4x4 matrices, unfortunately, matrix attributes are not returned as MEL 4x4 matrix types. Instead, they are returned as an array of floats where the elements of the matrix are listed in row major order. For instance, "matrix $m[4][4] = `getAttr ball.worldMatrix`;" will not work. To obtain the value of a matrix attribute, you need something like "float $m[16] = `getAttr ball.worldMatrix`;".

These float arrays (for a 4x4 matrix) are indexed like this:

0	1	2	3
4	5	6	7
8	9	10	11
12	13	14	15

xform command:

// Copy the worldspace matrix from pCube1 to pCube2:
// Using 'getAttr' on the .worldspaceMatrix, it calculates all
// scale operations based on all parental nodes as well.
// This can cause the target .shear attrs to be effected.
float $m[16] = `getAttr pCube1.worldMatrix`;
xform  -matrix $m[0] $m[1] $m[2] $m[3] 
		$m[4] $m[5] $m[6] $m[7] 
		$m[8] $m[9] $m[10] $m[11] 
		$m[12]$m[13] $m[14] $m[15] pCube2;

// you could optionally use this to get the matrix, via xform:
float $m[16] = `xform -query -matrix pCube1`;
// Which queries the .xformMatrix attr (see above), but this only 
// tracks the local scale values, not any extra parental scale
// values:  .shear attrs are not effected.

Sets/returns the composite transformation matrix. *Note* the matrix is represented by 16 double arguments that are specified in row order.

Matrix Nodes

decomposeMatrix (standard Maya plugin):
- See Mel Wiki notes here
addMatrix
- Add a list of matrices together.
fourByFourMatrix
- This node outputs a 4x4 matrix based on 16 input values. This output matrix attribute can be connected to any attribute that is type "matrix".
holdMatrix
- Cache a matrix.
multMatrix
- Multiply a list of matrices together.
passMatrix
- Multiply a matrix by a constant without caching anything
pointMatrixMult
- The dependency graph node to multiply a point by a matrix.
wtAddMatrix
- Add a weighted list of matrices together.

Matrix Commands

pointMatrixMult (mel)
- This script returns the multiplication of a point and a matrix as an array of 3 doubles. It is a wrapper around the pointMatrixMult node, which the script actually creates, modifies, gathers the return value, and then deletes.
- Located: C:/Program Files/Autodesk/Maya<version>>/scripts/others/pointMatrixMult.mel
For Python related matrix commands see: Working with matrices with Python

Syntax for authoring an identity transformation matrix:

matrix $m[4][4] = <<1, 0, 0, 0;
                    0, 1, 0, 0;
                    0, 0, 1, 0;
                    0, 0, 0, 1>>;

Printing 4x4 matrix data:

float $goo[] = `getAttr myNode.worldMatrix`;

for($i=1;$i<size($goo)+1;$i++)
	{
	print ($goo[$i-1] + " ");
	if($i%4==0)
		print("\n");
	}
1 0 0 0 
0 1 0 0 
0 0 1 0 
0 0 0 1

Using getAttr on a matrix attr will return back a float array. But when you want to do matrix math, you have to use the matrix variable type. These funtions will convert back and forth between the two:

global proc matrix floatArrayToMatrix(float $m[]){
	if(size($m) != 16)
		error("Please pass in a float array with exactly 16 elements");
	matrix $mat[4][4] = <<$m[0], $m[1], $m[2], $m[3];
					$m[4], $m[5], $m[6], $m[7];
					$m[8], $m[9], $m[10], $m[11];  
					$m[12], $m[13], $m[14], $m[15]>>; 
	return $mat;
	}

global proc float[] matrixToFloatArray(matrix $m){
	float $return[] = {};
	for($row=0; $row<4; $row++){
		for($column=0; $column<4; $column++)
			$return[size($return)] = $m[$row][$column];
		}
	return $return;
	}

Match the worldspaceMatrix of objectB to objectA:

string $source = "pCube1";
string $destination = "pCube2";

float $m[16] = `getAttr ($source+".worldMatrix")`;
xform -worldSpace  -matrix $m[0] $m[1] $m[2] $m[3] 
		$m[4] $m[5] $m[6] $m[7] 
		$m[8] $m[9] $m[10] $m[11] 
		$m[12]$m[13] $m[14] $m[15] $destination;

This will work, no matter what any parental groups have done to the nodes. Sweet.

Another snippet:
Have a destination node match the position of a hierarchy of source nodes. In this scene, "pCube1" is parented to "group1". The below code will match the worldspace matrix of "pCube2" to the postion of "pCube1" by multiplying the local matrices of "group1" and "pCube1" together.

string $sourceParent = "group1";
string $sourceChild= "pCube1";
string $destination = "pCube2";

// query the local matrix of the parent and child
matrix $matrixSP[4][4] = floatArrayToMatrix(`getAttr ($sourceParent+".matrix")`);
matrix $matrixSC[4][4] = floatArrayToMatrix(`getAttr ($sourceChild+".matrix")`);
// Generate our new  destination matrix, order is important!
matrix $dPos[4][4] = $matrixSC * $matrixSP;

float $m[16] = matrixToFloatArray($dPos);

xform -worldSpace  -matrix $m[0] $m[1] $m[2] $m[3] 
		$m[4] $m[5] $m[6] $m[7] 
		$m[8] $m[9] $m[10] $m[11] 
		$m[12]$m[13] $m[14] $m[15] $destination;
// it worked.  Trust me.

How can I create a RMB popup menu?

Tue, 16 Feb 2010 19:22:00 GMT

popupMenu

How can I find the min and max keyframe values for all objects in the scene?

Wed, 10 Feb 2010 01:44:00 GMT

Will return back a float array with two items, the [start, end] frames:

global proc float[] returnFrameRange(){
	select -r `ls -type "animCurve"`;
	return {float(`findKeyframe -which first`), float(`findKeyframe -which last`)};
}

float $frameRange[] = returnFrameRange();
// Result: 1 22 //

Also see:

How can I find the min and max keyframe range for the provided objects?

Wed, 10 Feb 2010 01:43:00 GMT

I seem to do this just not quite often enough to remember how to do it, so I'll make a note here.

Func returns a tuple containing the min and max frame range based on the list of nodes passed in.

# Python code
import maya.cmds as mc

def getMinMaxAnimRange(nodes):
    first = 0
    last = 0
    curves = mc.listConnections(nodes, source=True, destination=False, type='animCurve')
    if curves is not None:
        first = mc.findKeyframe(curves, which='first')
        last = mc.findKeyframe(curves, which='last')
    return (first, last)

Also see:

How can I find the min and max keyframe values for all objects in the scene?

How can I pickle Python data to attributes?

Tue, 09 Feb 2010 02:46:00 GMT

I blogged about it here:
http://www.akeric.com/blog/?p=1049

And notes on the Python functions:
http://docs.python.org/library/pickle.html
http://docs.python.org/library/pickle.html#module-cPickle
http://docs.python.org/library/stringio.html#module-StringIO

GuestBook

Mon, 08 Feb 2010 23:38:00 GMT

The Mel Wiki Guest Book
Since this wiki isn't opening to public editing (got too much spam), please email me your guest book entry, and I'll post it! — warpcat (at) sbcglobal (dot) net —
Please use this format in your mail:

Name\Handle:  Joe Bobson
Email (optional): joebob@bob.com
Comment:  Wow, what a great wiki!

Date: Feb 08, 2010
Name: Zhi Min Chen
Comment: Great website. I use it on a regular basis to help me on most my projects at work. Your wiki's question format is very well thought out and it makes finding answers extremely quick. Keep up the great work!

Date: Aug 15, 2008
Name: Ben Brac
Email: brac@sonic.net
Comment: Awesome wiki WarpCat! I use it all the time when the usual documentation leaves much to be desired. Keep the updates coming!

Date: Aug 06, 2008
Name: Bob Aunum
"Thank you sincerely. The subject says it all. since i decided to teach myself mel, i've been looking for a good web resource, but i really didn't expect to find anything as elegantly functional as your wiki. It's great. Really."

Date: May 19th, 2008
Name: Fridi Kühn
I am a student from Germany and have recently started helping a games developer to automate their process of animating. Since I am a beginner to MEL I wanted to state that your mel wiki helped me alot to overcome the mysteries of that language. I just wanted to thank you for your website and hope you will keep it alive! Please know that I will frequently return and see what's new...

How can I get a list of set membership in the proper order every time?

Mon, 01 Feb 2010 22:10:00 GMT

listConnections -s 1 -d 0 -p 0 -c 0 "setName";

Note: Often times, one would think they could simply select the set, and use the ls command to get an array of membership. The problem is, the ls command will return them in a different order than the Outliner may show. Furthermore, the order seems to change from time to time (hard to confirm this). When an item is "added" to a set, what's actually happening is the set has a new attribute generated, and that attr is connecting to the object. By using the "listConnections" command, we can get a list, in order, of all the attribute connections. The order still may be different than what's shown in the Outliner, but at least it should be consistant.
There is only one caveat: The listConnections command will return DG objects in a set before it lists DAG objects. If you don't have mixed data types in your sets, then there is no issue. However, if you have both DG and DAG objects in the set, then you still could run into future problems of shifting order in the return value.

How can I have Wing send Python or mel code to Maya?

Mon, 01 Feb 2010 21:52:00 GMT

I using Wing IDE for authoring Python and mel code for Maya, and have come up with a solution (presuming you have the 'Professional' version of Wing) to have the code you highlight in Wing execute in Maya (aka 'evaluate selection'). This lets me completely replace the Script Editor when authoring Python or mel, which we all know doesn't have the best Python integration... :-S

I've added some updated code below that now allows you to publish mel code from Wing to Maya as well.
Note that you can also have Wing recognize .mel files, with some (not full) context sensitive highlighting, correct indentation, scope hilighting, etc: Under Wing 'Prefs -> Files -> File Types', 'insert' a new file type as mel and set its 'Mime Type' to be C++ Source.

There are a few steps involved to get this working. I should point out again this only works with the 'Professional' version of Wing, and you'll need Maya v8.5 or newer: when Maya started supporting Python (below this section I list some old code, for version of Maya8.5 and earlier.)

1. In Maya's userSetup.mel file, add this line to open a network socket. This will later let Wing talk with Maya.

// userSetup.mel
commandPort -name ":6000" -echoOutput;

It appears, if you're running Maya on Vista \ 64bit, or maybe it's a Maya2010 thing, you need to call to commandPort twice to get this working, otherwise your socket will later be refused:

// userSetup.mel
commandPort -name "127.0.0.1:6000" -echoOutput;
commandPort -name ":6000" -echoOutput;

For whatever reason, having your userSetup.py execute these commands instead won't let the below process work. This really confuses me, since Maya claims the port is open. But Wing says the port is refused....

2. This Wing Python module (wingHotkeys.py) and functions inside are authored to do a few things:

A. Save the text selected in Wing as a temp file on disk.
B. Ping Maya through the opened command port, and tell Maya to execute the contents of that file. Depending on the type of data sent, either Python or mel, the tool will tell Maya how to intercept it, and execute it.

Again, this code is tailored to Wing IDE's API, and saved as part of that program's own "scripts" directory. Default location (on winXP) of that dir is here:

C:\Documents and Settings\<userName>\Application Data\Wing IDE 3\scripts

send_to_maya() : Function that does the heavy lifting
python_to_maya() : Wrapper to send the code as Python to Maya. I have this mapped to ctrl+p. (Wing hotkeys don't allow args, so you need to author wrapper functions)
mel_to_maya() : Wrapper to send the code as mel to Maya. I have this mapped to ctrl+m.

If you already have a wingHotkeys.py module for Wing, you can just add the below code to it:

# wingHotkeys.py
# Author:  Eric Pavey - warpcat@sbcglobal.net

import wingapi
import socket
import os

def getWingText():
   """
   Based on the Wing API, get the selected text, and return it
   """
   editor = wingapi.gApplication.GetActiveEditor()
   if editor is None:
      return
   doc = editor.GetDocument()
   start, end = editor.GetSelection()
   txt = doc.GetCharRange(start, end)
   return txt

def send_to_maya(language):
   """
   Send the selected code to be executed in Maya

   language : string : either 'mel' or 'python'
   """
   if language != "mel" and language != "python":
      raise ValueError("Expecting either 'mel' or 'python'")

   # Save the text to a temp file.  If we're dealing with mel, make sure it
   # ends with a semicolon, or Maya could become angered!
   txt = getWingText()
   if language == 'mel':
      if not txt.endswith(';'):
         txt += ';'
   tempFile = os.path.join(os.environ['TMP'], 'wingData.txt')
   f = open(tempFile, "w")
   f.write(txt)
   f.close()

   # Tell Maya to execute the temp file:
   maya = socket.socket(socket.AF_INET, socket.SOCK_STREAM)
   #Optional way of doing it, if using Vista:
   #maya = socket.socket(socket.AF_INET6, socket.SOCK_STREAM)
   try:
      # Sometimes connect likes to complain, not sure why
      maya.connect(("127.0.0.1", 6000))
      # Optional way of doing it, if using Vista:
      # maya.connect(("::1",6000))
      if language == "mel":
         maya.send('execMelCode();')
      if language == "python":
         maya.send('python("import execPythonCode; execPythonCode.main()")')
   except:
      maya.close()
   maya.close()

def python_to_maya():
   """Send the selected Python code to Maya"""
   send_to_maya('python')

def mel_to_maya():
   """Send the selected code to Maya as mel"""
   send_to_maya('mel')

3. This Python module execPythonCode.py is the one Wing's send_to_maya('python') function (above, step 2) triggers: In Maya, it uses the Python exec command to execute the code in the file saved on disk.
Be sure to save this in a location seen by Maya's Python path.

# execPythonCode.py
# Author:  Eric Pavey - warpcat@sbcglobal.net

import __main__
import os

def main():
    """
    exec the temp file on disk, in Maya
    """
    tempFile = os.path.join(os.environ['TEMP'], 'wingData.txt')
    if os.access(tempFile , os.F_OK):
        # open and print the file in Maya:
        f =  open(tempFile , "r")
        lines = f.readlines()
        for line in lines:
            print line.rstrip()
        f.close()
        print "\n",
        # execute the file contents in Maya:
        f = open(tempFile , "r")
        exec(f, __main__.__dict__, __main__.__dict__)
        f.close()
    else:
        print "No temp file exists: " + tempFile

The key here, is the exec command updating the __main__.__dict__ dictionary with any defined variable names passed in from Wing. It is effectively adding them to the 'main', or 'builtin' scope of Python. If this doesn't happen, after the code is executed, you won't be able to access any variables created\changed from within Maya.

4. This mel script allows for the temp file saved by Wing to be executed as mel in Maya. It to is triggered via the Wing send_to_maya('mel') Python function.
Be sure it is saved as part of Maya's script path.

// execMelCode.mel
// Author:  Eric Pavey - warpcat@sbcglobal.net

global proc execMelCode(){
    string $tempFile = (`getenv "TMP"`+"/wingData.txt");
    if (`filetest -f $tempFile`){
        // open and print the file in Maya:
        int $fid = `fopen $tempFile "r"`;
        string $line = `fgetline $fid`;
        string $printer = strip($line);
        if(size($printer) > 0){
            print $line;
        }
        while ( size($line) > 0){
            $line = `fgetline $fid`;
            $printer = strip($line);
            if(size($printer) > 0){
                print $line;
            }
        }
        fclose $fid;
        print "\n";
        eval("source \""+$tempFile+"\"");
    }
    else{
        print ("No temp file exists: " + $tempFile + "\n");
    }
}

We jump through some hoops to get it printed correctly, and at the end, we simply source the script to execute its contents.

5. That's it: You can now highlight code in Wing (either Python or mel), and via a wing hotkey, have it execute directly in Maya. I use it every day...

Older methods:

For Maya versions 8 and earlier (Maya 8.5 has Python embedded, yah!)
Thanks to Hamish McKenzie "macaroniKazoo" on highend3d.com
First, in Maya, create an INET domain on the local host at the command port:
- Win2000 syntax is "computerName:portNumber", I've wondered why you don't have to specify the computerName here?

commandPort -n ":5055";

Second, in Python:

import socket
maya = socket.socket(socket.AF_INET, socket.SOCK_STREAM)
maya.connect(("127.0.0.1", 5055))

Then, to actually have Python talk to Maya:

maya.send('print "I am typing in Python, but I see it in Maya!\\n";')

Of course, you have to embed your mel commands in the Python syntax.
Python library docs on 'socket' HERE
What's so special about '127.0.0.1'? Check Wikipedia HERE

For Python: Maya 'Script Editor' style IDE

Fri, 22 Jan 2010 18:28:00 GMT

I've been looking for a LONG time, trying to find an IDE for Python that mirrored one important feature from Maya's Script Editor: Evaluate Selection, which is the ability to highlight blocks of code, and execute just that block interactively.

Maya's implementation of Python in the Script Editor can do this (since version 8.5), but what if you want to author Python outside of Maya, but still have this functionality?

After asking a lot of people, and doing a lot of searching, I finally found Wing:
http://www.wingware.com/

Wings docs on integrating with Maya here (which actually links back to this page :-) )
It has three versions:

Wing IDE 101 (free, but doesn't have 'Evaluate Selection')
- Update: It appears you can hack it: I saw this post in a forum, from Wingware itself:

It looks like the keyboard config pref is omitted in 101. You could
hack it by editing the keyboard.normal file in the Wing installation
and adding:
'Ctrl-F5': 'evaluate-file-in-shell'
Or to evaluate the current selection:
'Ctrl-Shift-F5': 'evaluate-sel-in-shell'
You'll need to restart Wing to read those and you can of course alter
the bindings. Also, if you're using one of the other keyboard
personalities you should edit the associated keyboard.* file instead.

Wing IDE Personal ($35)
Wing IDE Professional ($179 - Lets you access the Wing API via Python, to write your own plugins for the tool + other features)

Compare version features:
http://www.wingware.com/wingide/features

More Wing Goodness:

Notes:

Wing itself runs a different version of Python than you may have installed. The current version of Wing (as of this update) runs Python 2.5.4. This is only really important if you get the "Pro" version, and start making your own 'plugin scripts': The plugins you author will be running Wings version of Python, not your installed version of Python. Furthermore, the Wing distribution isn't the full install of Python, so not all modules are available. This isn't a huge deal, but it's important to be aware of if your plugins don't work. For example, I had one that called to the webbrowser module: That module isn't distributed with Wing. Luckily, they have their own function (wingapi.gApplication.OpenURL(url)) that could be used in its place.

Also see:

How can I execute Maya's version of Python outside of Maya?

Also, as of v1.7 of the 'jEdit Maya Editor Plugin' (see: Script Editor Replacements), this 'evaluate selection' functionality has been implemented (as informed by its author).

Source Analysis in Wing

Fri, 22 Jan 2010 18:26:00 GMT

NOTE: Wing has been updating their own tutorials on this, take a look at them here:
http://www.wingware.com/doc/howtos/maya
A some of their tutorial came from my troubleshooting with their support team (which is great by the way), and actually links back to this wiki :-)
The tutorial below were steps I was taking to get this working.

Tutorial done on Windows Vista.
This will get 'source analysis' of the Maya API working in Wing. Will allow for such nice things as auto-completion. Here are some links I found on the subject, but none of them got me exactly to where I needed to be. But they all helped ;)

Get the API OpenMaya calls working:

Make 'pi file' dir here:

C:\Users\epavey\AppData\Roaming\Wing IDE 3\pi-files\maya

Copy the Wing-made .pi files to that dir from here:

C:\Users\epavey\AppData\Local\Wing IDE 3\pi-cache\2.6\C\Program Files\Autodesk\Maya2010\Python\Lib\site-packages\maya

Remove all the underscores from the front of the .pi files:
- _OpenMaya.pi rename to OpenMaya.pi
In Wing's prefs, go : Source Analysis -> Advanced -> Interface File Path -> Insert.
- And add the directory you made above.
Restart Wing
Now, when you enter the below code, Wing should start to auto-populate the command list:

import  maya.OpenMaya as om
om. # <-- Wing should now populate that attribute list.

Note, it seems like the below won't work. You need to use the above example:

import maya.OpenMaya
maya.OpenMaya. # <-- no auto-complete :(

Get the mel.cmds calls working:

At the time of this authoring, it appears that it's a 'bug' in Wing that doesn't let it see the maya.cmds pacakge. However, after working with Wing they made a patch, that should be available in future versions. So the below data really doesn't have any effect... yet...

You'll need to make your own .pi file for the maya.cmds package. To do that, first you'll have to get Maya running inside of wing. See this wiki post: How can I execute Maya's version of Python outside of Maya?
Use this code to auto-generate the .pi file. You can see my blog post here on more of the specifics.

import maya.cmds as mc

filepath = 'c:/temp/cmds.pi'
f = open(filepath, mode='w')

for k in sorted(mc.__dict__.keys()):
    f.write('def %s():\n'%k)
    f.write('    pass\n')
    f.write('\n')
f.close()

Copy the cmds.pi file to the directory you made above under 'Get the API OpenMaya calls working'.
And then.... (currently not working.... )

How can I specify 'all keys' when cutting or pasting in Python?

Wed, 20 Jan 2010 21:42:00 GMT

In mel, when copying or pasting all keframes, the syntax is pretty simple (replace ... with the rest of the command code):

cutKey -time ":" ... ;

And even the Python command docs say this:

-time ":" is a short form to specify all keys.

But that's not how the Python formatting actually works.
Per Maya Docs -> User Guide -> General -> Python -> Using Python -> Ranges ->
You need to specify the time settings in this format:

mc.cutKey(time=(":",), ...)

2010 01 20

Wed, 20 Jan 2010 21:37:00 GMT

Added the HARDWARE category. Currently only has one item. But it's a cool item. I'm not sure how I'd use it, but I think it deserves its own category ;)

Blog

Wed, 20 Jan 2010 21:37:00 GMT

The mel wiki blog.

2010 01 20 - Added the HARDWARE category.
2010 01 13 - Added the INFO category.
2009 05 13 - Added API category
2008 11 19 - Updated Python tagging
2008 08 14 - Created the Mel Wiki Guest Book
2008 07 05 - A new mel tiddlywiki online!
2008 06 08 - Blog about my new blog (blog blog blog)
2008 05 21 - tiddlywiki upgraded
2008 05 20 - Python Wiki!
2008 03 31 - More Processing.
2008 03 11 - Added 'Other Links'
2008 03 07 - Added the TROUBLESHOOTING category.
2008 02 18 - Processing!
2008 01 29 - Added All Subjects tiddler.
2008 01 08 - New feature: Visual Guide of UI Controls
2008 01 07 - Tiddlyspot back up. And... robots!
2008 01 04 - rain! Tiddlyspot down...
2008 01 02 - New PYTHON category, update wiki UI formatting.
2007 04 27 - mel wiki is born

How can I have a node return the worldspace position of my object, offset in time?

Wed, 20 Jan 2010 21:28:00 GMT

Worldspace Matrix

If you're only interested in translation values, you can query a nodes worldMatrix attr to get this info directly from the node in question:

string $node = "pSphere1";
float $offset = 1.0;
float $t = `currentTime -q`;
float $worldMatrix[] = `getAttr -t ($t- $offset) ($node+".worldMatrix")`;
vector $offsetTranslate = <<$worldMatrix[12], $worldMatrix[13], $worldMatrix[14] >>;
print $offsetTranslate;

decomposeMatrix node

Before I had a better understanding of nodes matrix attrs, I used to use this method:

The decomposeMatrix plugin wil help do the trick (got the info for this tip in a forum by Lutz Paelike)
I'm not a big fan of plugins in development, they can really cause a bottleneck, but since this plugin is distributed with Maya, I find it safer than usual.
What the decomposeMatrix node does, among other things, is let you pass in a source matrix, and it will spit out the worldspace trans, rot, scale, and shear for that matrix. From there, we can use getAttr -t to query those values in time.
Given this concept, regardless of your source objects hierarchical transformations, as long as your destination object lives in worldspace, it will follow along happily in time:

First, load the "decomposeMatrix.mll" plugin:

int $isLoaded = `pluginInfo -q -l "decomposeMatrix.mll"`;
if (!$isLoaded)
    loadPlugin "decomposeMatrix.mll";

Next create the decomposeMatrix node:

string $dm = `createNode decomposeMatrix`;

given you have an object with it's name in ' string $obj = "myObj" ', connect:

connectAttr -f ($obj + ".worldMatrix[0]") ($dm + ".inputMatrix");

Now you can query the decomposeMatrix's output attrs to find the worldspace transformations. (or, you could connect them to another node, for a direct connection situation) And if we make an *expression* in like the link below, you can query them in time, to generate lag:

float $t = `currentTime -q`;
followObj.translateX = `getAttr -t ($t - 10) decomposeMatrix1.outputTranslateX`;

Also see:

How can I compute distance traveled in an expression?

Wed, 20 Jan 2010 21:18:00 GMT

Old example:

// compute current position:
float $posNowX = obj.translateX;
float $posNowY = obj.translateY;
float $posNowZ = obj.translateZ;

// compute previous position:
float $posThenX = `getAttr -t (frame - 1) obj.translateX`;
float $posThenY = `getAttr -t (frame - 1) obj.translateY`;
float $posThenZ = `getAttr -t (frame - 1) obj.translateZ`;

// compute distance traveled per frame:
float $distance = sqrt( pow(($posNowX - $posThenX), 2) +
pow(($posNowY - $posThenY), 2) +
pow(($posNowZ - $posThenZ), 2) );

print ($distance + "\n");

Newer example: (thanks Jamie McCarter)

float $t = `currentTime -q`;
vector $currentP = `getAttr object.translate`;
vector $previousP = `getAttr -t ($t-1) object.translate`;
float $dist = mag( $currentP - $previousP );
print( "distance travelled " + $dist + "\n");

Newer, with matrices! ;) Probably the most accurate way of doing it?

float $t = `currentTime -q`;

float $curM[] = `getAttr object.worldMatrix`;
float $prevM[] = `getAttr -t ($t-1) object.worldMatrix`;
vector $currentP = <<$curM[12], $curM[13],$curM[14]>>;
vector $previousP = <<$prevM[12], $prevM[13],$prevM[14]>>;
float $dist = mag( $currentP - $previousP );

print( "distance travelled " + $dist + "\n");